固有空間とローレンツ曲線

15.固有空間
100 rem koyuu-kuukann
110 graphics 0
120 graphics window 400,400
130 graphics moveto 200,75 : lineto 200,325
140 graphics moveto 50,200 : lineto 350,200
150 graphics color 100,0,0
160 a11 = 1 : a12 = 0.6 : a21 = 0.25 : a22 = 0.75 : rem keisuu
170 for x = -100 to 100 step 20
180  for y = -100 to 100 step 20
190   xx = a11*x+a12*y
200   yy = a21*x+a22*y
210   graphics moveto x+200,-y+200 : lineto xx+200,-yy+200
220   graphics circle 5
230  next y
240 next x
250 end
解説)
固有ベクトルを図示したらどのようになるのかと思い作りました。この図で、固有
空間の意味が少しは分かった気がします。200行目のcircleは、円を描く命令です。
5は、円の大きさです。

16.ローレンツ曲線
100 rem lorentz 
110 rem dx/dt=10(y-x)
120 rem dy/dt=-xz+28x-y
130 rem dz/dt=xy-8z/3
140 rem 0.50617,0.506
150 rem
160 x = 0.9 : y = 16 : z = 0.19
170 dt = 1.000000E-03
180 print x,y,z,dt
190 graphics 0
200 graphics window 450,350
210 graphics color 0,0,0
220 graphics moveto 200,200 : lineto 200,50
230 graphics moveto 200,200 : lineto 350,200
240 graphics moveto 200,200 : lineto 110,290
250 graphics color 100,0,0
260 rem
270 for i = 1 to 50000
280  dx = 10*(y-x)*dt
290  dy = (-x*z+28*x-y)*dt
300  dz = (x*y-z*8/3)*dt
310  x = x+dx
320  y = y+dy
330  z = z+dz
340  if (i mod 100) = 0 then print i*dt,x,y,z
350  graphics pset (y-x)*3+200,200-(z-x)*3
360 next i
370 end
解説)
ローレンツの式による曲線です。カオスはこれから始まったと言えます。この曲線を
見たくて、しばらくやっていなかったプログラムを再開しました。取り立てて説明す
るところはないかと思います。350行目で単に点をプロットするだけでなく、３次元
に見えるようにしています。