肥満度と木

7.肥満度の計算
100 rem Himando
110 cls
120 print "Anata no Himando wo hakarimasu."
130 input "Anata no Shinchou wa? ",shin
140 input "Anata no Taijuu wa? ",tai
150 ss = (shin-100)*0.9
160 print "Risou-taijuu=";ss
170 if ss*0.8 > tai then print "Yasesugi desu." : goto 220
180 if ss*0.9 > tai then print "Yaya Yasesugi desu." : goto 220
190 if ss*1.2 < tai then print "Hutorisugi desu." : goto 220
200 if ss*1.1 < tai then print "Yaya Hutorisugi desu." : goto 220
210 print "Choudo Yoi Karada desu."
220 end
解説)
肥満度を計算するプログラムです。特別なことは全然やっていません。
あえて言えば、clsは画面のクリアです。
また、goto文で飛ばしていますが、この場合は、ifの後だから許されるでしょう。
質問がローマ字になっているのは、Chipmunk-BASICが日本語に対応していないためです。
ローマ字で質問を作っていると二十年ほど昔のパソコンが出たばかりの頃を思い出します。

8.木
100 rem random-tree
110 randomize timer
120 dim a(10)
130 mat a = 3
140 graphics 0
150 graphics window 600,450
160 graphics moveto 300,300
170 graphics lineto 300,400
180 for j = 1 to 200
190   theta = 0.25*pi : r = 300 : x = 0 : y = 100 : s = 0.5*pi
200  for i = 1 to 10
210    z = rnd(2)
220    if z = 1 then s = s-theta :  else s = s+theta
230    r = 0.5*r
240    xx = x+r*cos(s) : yy = y+r*sin(s)
250    graphics moveto x+300,400-y
260    graphics lineto xx+300,400-yy
270    x = xx : y = yy
280  next i
290 next j
300 end
解説)
木を描くプログラムです。ただ、乱数を用いて枝をつけていくところが違います。
mat a=3で行列a()の総てに3が入ります。
piは予約語で円周率です。
200行目のif, then, elseの使い方が使い方が普通のBASICと違いますので注意して下さい。
elseの前には必ず:(コロン)をつけて下さい。