図形2題

まずは、リサージュ図形から
1.リサージュ(次の１００から２３０までをコピーし、テキストファイルにして使って下さい。)
100 rem Lisague 
110 graphics 0
120 graphics window 600,500
130 graphics color 100,0,0
140 rx = 40 : ry = 30
150 for i = 1 to 7
160  for t = 1 to 50 step 0.1
170   x = rx*cos(t)
180   y = ry*sin(0.1*i*t)
190   if t = 1 then graphics moveto x+80*i,-y+50*i
200   graphics lineto x+80*i,-y+50*i
210  next t
220 next i
230 end

解説)
単に数種類のリサージュを書くプログラムです。
100,120,は行番号。BASICでは必ずいります。
remはremark、この後にコメントを書くことができます。
graphics 0はグラフィック・ウインドウを開きます。グラフィック関係はマック特有の命令になっています。
120 graphics window 600,500はウインドウの大きさを横６００ドット、縦５００ドットの大きさとします。
130 graphics color 100,0,0は、線の色をきめます。100,0,0は赤です。
movetoとlinetoはグラフィックの線の起点と終端です。
for,nextはループです。0.1刻みで５０回くり返します。ここでは、これをさらに７回くり返しています。
endはプログラムのおしまいにつけるおまじないです。

2.多角形(次の100から250までをコピーし、テキストファイルにして使って下さい。)
100 rem graphs 多角形
110 graphics 0
120 graphics window 400,300
130 for j = 1 to 8
140   theta = j*pi*0.1
150   w = pi-theta
160   x = 0 : y = 0
170   graphics moveto 60*j,50*j
180   for i = 1 to 152
190     x = x+i*cos(i*w)
200     y = y+i*sin(i*w)
210     graphics lineto x+60*j,y+50*j
220   next i
230 rem
240 next j
250 end

解説)
多角形(?)を描くプログラムです。
ほとんど上のプログラムと変わりありませんが、cos(),sin()というコサイン、サインを求める関数を使ったのだけが違うところです。
wで角度を求めています。角度は、度数でないことに注意して下さい。
100 rem graphs 多角形　のようにremの中に漢字を書いておくこともできます。